Excel, Formeln, VBA Programmierung, UDF, Tipps & Tricks

Getrennte Daten lückenlos auflisten

Excelformeln - Getrennte Daten einer Spalte untereinander darstellen.

Nachfolgend eine mögliche Lösung um getrennte Daten einer Spalte, mit oder ohne zusätzliche Kriterien, an anderer Stelle lückenlos untereinander darzustellen.

Die Formeln können jeweils nach unten kopiert werden.

Getrennte Daten

	A	B	C	D	E	F	G
1	Kriterium1	Kriterium2	Wert
2	b	c	10
3
4	a	d	6
5	a	d	18
6
7
8	a	c	5
9
10
11	b	d	12
12	a	c	14
13
14
15	Formel-Nr						Ergebnis
16	1	Listet die Werte aus Spalte C lückenlos untereinander					10
17	2	Listet die Werte aus Spalte C lückenlos untereinander wenn Kriterium1 = a					6
18	3	Listet die Werte aus Spalte C lückenlos untereinander wenn Kriterium1 = a und Kriterium2 = c					5
19

Formeln der Tabelle

G16 : {=WENN(ANZAHL2(A:A)<ZEILE(A2);"";INDEX($A$2:$C$12;KKLEINSTE(WENN($A$2:$A$12<>"";ZEILE($1:$11));ZEILE(A1));3))}
G17 : {=WENN(ZÄHLENWENN($A$2:$A$12;"a")<ZEILE(A1);"";INDEX($A$2:$C$12;KKLEINSTE(WENN($A$2:$A$12="a";ZEILE($1:$11));ZEILE(A1));3))}
G18 : {=WENN(ISTFEHLER(INDEX($A$2:$C$12;KKLEINSTE(WENN($A$2:$A$12="a";WENN($B$2:$B$12="c";ZEILE($1:$11)));ZEILE(A1));3));"";INDEX($A$2:$C$12;KKLEINSTE(WENN($A$2:$A$12="a";WENN($B$2:$B$12="c";ZEILE($1:$11)));ZEILE(A1));3))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download

Sind die Daten waagerecht angeordnet, hier grün markierte in Zeile 1 ( A1 bis J1 ), so können folgende Formeln genutzt werden.

Einmal zur senkrechten sowie zur waagerechten Anordnung.

Getrennte Daten2

	A	B	C	D	E	F	G	H	I	J
1	1		5		8		10	12
2
3
4	Senkrecht		Waagerechte Darstellung
5	12		12	10	8	5	1
6	10
7	8
8	5		Waagerechte Darstellung mit Fehlerbehandlung
9	1		12	10	8	5	1
10

Formeln der Tabelle

A5 : {=INDEX($A$1:$J$1;1;KGRÖSSTE(WENN(MTRANS($A$1:$J$1)<>"";ZEILE($1:$10));ZEILE(A1)))}
C5 : {=INDEX($A$1:$J$1;1;KGRÖSSTE(WENN(MTRANS($A$1:$J$1)<>"";ZEILE($1:$10));SPALTE(A1)))}
C9 : {=WENN(ISTFEHLER(INDEX($A$1:$J$1;1;KGRÖSSTE(WENN(MTRANS($A$1:$J$1)<>"";ZEILE($1:$10));SPALTE(A1))));"";INDEX($A$1:$J$1;1;KGRÖSSTE(WENN(MTRANS($A$1:$J$1)<>"";ZEILE($1:$10));SPALTE(A1))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download

Die Formel können jeweils nach unten bzw rechts kopiert werden.